PowerPoint (全般)

PowerPoint 全般に関する話題を扱うフォーラムです。
  • 掲示板への投稿には会員登録(無料)が必要です。会員登録がまだの方はこちら
  • 掲示板ご利用上のお願い」に反するご記入はご遠慮ください。
  • Q&A掲示板の使い方はこちらをご覧ください
トピックに返信
質問

 
(Windows 10全般 : PowerPoint 2016)
POWERPOINTのスライドにノートも入れてPDFを作成する方法
投稿日時: 18/06/23 15:38:48
投稿者: cdznaka

EXCELのVBAで、POWERPOINTのファイルをPDFファイルにするのですが、ノート部分もPDFにするやり方を教えてください。
エクスポートで、オブジェクト.ExportAsFixedFormat ファイル名 ppFixedFormatTypePDF,ppPrintOutNotePages
,ppFixedFormatIntentScreen,msoTrue
と指定しました。また、説明が掲載された場所がわかればそちらでも結構です。
上記を設定する上で参考にしたのは下記リンク先ですがよくわかっていません。よろしくお願いします。
https://msdn.microsoft.com/ja-jp/vba/powerpoint-vba/articles/presentation-exportasfixedformat-method-powerpoint

回答
投稿日時: 18/06/23 19:06:48
投稿者: んなっと

ツール→参照設定→Microsoft PowerPoint 16.0 Object Library としてしまうのが楽です。
 
Sub PPT2PDF()
  'ツール→参照設定→Microsoft PowerPoint **.0 Object Library
  Dim fd As FileDialog 'ファイルダイアログ
  Dim objPpt As PowerPoint.Application
  Dim myPre As PowerPoint.Presentation
  Dim i As Long
  Dim myN As String
  '任意のファイル選択
  Set fd = Application.FileDialog(msoFileDialogFilePicker)
  With fd
    .AllowMultiSelect = True
    .Filters.Add "PowerPointファイル", "*.ppt; *.pps; *.pptx; *.pptm", 1
    If .Show <> -1 Then Exit Sub
  End With
  'パワーポイント起動
  Set objPpt = CreateObject("PowerPoint.Application")
  objPpt.Visible = True
  For i = 1 To fd.SelectedItems.Count
    Set myPre = objPpt.Presentations.Open(fd.SelectedItems.Item(i), msoTrue)
    myN = Mid(myPre.FullName, 1, InStrRev(myPre.FullName, ".") - 1) & ".pdf"
    myPre.ExportAsFixedFormat myN, ppFixedFormatTypePDF, ppFixedFormatIntentScreen, msoTrue, , ppPrintOutputNotesPages
    myPre.Close
  Next i
  objPpt.Quit
  Set myPre = Nothing
  Set objPpt = Nothing
End Sub

トピックに返信