Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 10 Home : Excel 2016)
特定の文字列取得
投稿日時: 18/06/03 17:47:10
投稿者: グルグル

お世話になります。
少し困っています。
 
A列   B列
12/34/56   56
12/345/678  678
 
A列の文字をB列に取得する関数をご教授お願いします。

回答
投稿日時: 18/06/03 18:09:38
投稿者: WinArrow
投稿者のウェブサイトに移動

2つ目の"/"の右側の文字列
というのか
最後の"/"の右側も文字列
というのかで、対応が変わってくるのではないでしょうか?
 
文章でキチンと伝えるよう、お願いします。

回答
投稿日時: 18/06/03 18:12:22
投稿者: WinArrow
投稿者のウェブサイトに移動

関数でなくてもよいなら
「区切り位置」コマンドで対応できますが・・・・

投稿日時: 18/06/03 18:21:35
投稿者: グルグル

失礼しました。補足します。
 
A列    B列
入荷/残/予定  予定
12/34/56    56
12/345/678   678
 
A列の入荷/残/予定の中から予定の部分だけを
B列に取得する関数をご教授お願いします。

回答
投稿日時: 18/06/03 18:25:36
投稿者: WinArrow
投稿者のウェブサイトに移動

一寸、長くなるけど・・・
SUBSTITUTE関数を駆使して
最後の"/"を"!"の変更して、"!"以降の文字列を取り出します。
 
=MID(SUBSTITUTE(A1,"/","!",LEN(A1)-LEN(SUBSTITUTE(A1,"/",""))),FIND("!",SUBSTITUTE(A1,"/","!",LEN(A1)-LEN(SUBSTITUTE(A1,"/",""))))+1,10)

回答
投稿日時: 18/06/03 18:35:38
投稿者: WinArrow
投稿者のウェブサイトに移動

↓こっちの数式の方がスマートかも・・・
 
=RIGHT(A1,LEN(SUBSTITUTE(A1,"/","!",LEN(A1)-LEN(SUBSTITUTE(A1,"/",""))))-FIND("!",SUBSTITUTE(A1,"/","!",LEN(A1)-LEN(SUBSTITUTE(A1,"/","")))))

回答
投稿日時: 18/06/03 18:58:28
投稿者: んなっと

こんなのも。
=TRIM(RIGHT(SUBSTITUTE(A1,"/",REPT(" ",100)),100))

回答
投稿日時: 18/06/04 09:46:19
投稿者: ゆーたん

趣味の別案です。予定が8文字までとして。(^_^;)
 
=VLOOKUP("/*",INDEX(RIGHT(A1,ROW($1:$9)+{0,-1}),),2,)

回答
投稿日時: 18/06/04 10:52:28
投稿者: ゆーたん

ごめんなさい、数値っぽいですね。(T_T)
んなっとさんので1かけといたほうがいいのかも。
 
=RIGHT(SUBSTITUTE(A1,"/",REPT(" ",9)),9)*1

回答
投稿日時: 18/06/04 12:23:21
投稿者: んなっと

なるほど、グルグルさんの2回目の書き込みを見れば、数値のほうがいいですね。
ありがとうございます、師匠。

投稿日時: 18/06/10 15:01:12
投稿者: グルグル

こんにちは。
1週間の放置申し訳ございません。
 
WinArrowさん、んなっとさん、ゆーたんさん回答ありがとうございます。
 
今回は=RIGHT(SUBSTITUTE(A1,"/",REPT(" ",9)),9)*1をつかわせて頂きます。
 
ありがとうございました。