Excel (一般機能)

Excelの一般機能に関するフォーラムです。
  • 解決済みのトピックにはコメントできません。
このトピックは解決済みです。
質問

 
(Windows 7 Professional : Excel 2010)
行で検索して1個左の文字を取得
投稿日時: 18/05/31 14:03:19
投稿者: you_ku

2行目に下記のように記載があります。
2行目は固定で、1行目になったり、3行目になったりはしません。
 
一番右端の『結果』と表示されているセルを2行目から探して、その左の文字、この場合は『MAR 17』を表示する関数を教えてください。
A3セルに表示させたいです。
 

	A	B	C	D	E	F	G	H
2	DEC 17	結果	JAN 17	FEB 17	MAR 17	結果		

 
なお、この表は翌月になると、右にずれていきます。(以下)
翌月には、A3セルに『APR 18』となるようにしたいです。
 
	A	B	C	D	E	F	G	H
2	DEC 17	結果	JAN 17	FEB 17	MAR 17	APR 18	結果		

 
 
よろしくお願いします。

回答
投稿日時: 18/05/31 14:22:20
投稿者: メジロ

このようなことでしょうか?
 
=INDEX(2:2,COUNTA(2:2)-1)

回答
投稿日時: 18/05/31 14:44:28
投稿者: Mike

you_ku さんの引用:
翌月には、A3セルに『APR 18』となるようにしたい
と仰っているにも拘わらず、お示しの
	A	B	C	D	E	F	G	H
2	DEC 17	結果	JAN 17	FEB 17	MAR 17	APR 18	結果		
は、F2セルが『APR 18』になっているのは何故?!

回答
投稿日時: 18/05/31 14:53:27
投稿者: ゆーたん

一応そのまま案です。(^_^;)
 
=INDEX(2:2,MATCH(1,0/(2:2="結果"))-1)
 
配列確定(Ctrl+Shift+Enter同時押しで確定)。

回答
投稿日時: 18/05/31 14:57:39
投稿者: コナミ

>Mikeさん
 
翌月分が足されてF2に『APR 18』が入ったから、A3にそれを表示させたいということじゃないですか?
文章読めばわかると思いますが。

回答
投稿日時: 18/05/31 15:00:36
投稿者: ゆーたん

ちょっと「同時押し」は言い方が悪いかな、すみません。(T_T)
配列確定
式入力後、Enterキー等で通常確定せず、
CtrlキーとShiftキーを同時に押しながら、さらにEnterを押して確定する、
特別な確定方法です。

回答
投稿日時: 18/05/31 15:12:07
投稿者: んなっと

    A   B    C    D    E    F   G
2 Dec 17 結果 Jan 17 Feb 17 Mar 17 Apr 18 結果
3 Apr 18
                      
これは列挿入の際に不具合が発生する可能性がある式ですが...
A3
=LOOKUP(1,0/(B2:ZZ2="結果"),A2:ZY2)
 
※ Apr 18 が日付シリアル値であれば、こんなのも
A3
=LOOKUP(10^10,2:2)

回答
投稿日時: 18/05/31 16:39:04
投稿者: んなっと

あとこんなのもあるかもしれませんが...
A3
=LOOKUP(1,0/(B2:ZZ2="結果"),2:2)
 
...やはり、ゆーたんさんの式が確実ですね。

回答
投稿日時: 18/05/31 16:54:51
投稿者: ゆーたん

んなっとさん
>=LOOKUP(1,0/(B2:ZZ2="結果"),2:2)
これは短くしたかった意味が強いかな?(笑)
 
これ、LOOKUPの第2と第3、大きさ違っても行けるんですね…。
そうだったかー。勉強になりました。(^_^;)

回答
投稿日時: 18/05/31 17:05:21
投稿者: んなっと

引用:
短くしたかった意味が強い

まさにその通りです!
あと「不具合」のうち、「ZZ列を選択して列挿入」したら"2列ずれ"になってしまうのを防ぐ目的もあります。

投稿日時: 18/05/31 17:16:18
投稿者: you_ku

色々とアドバイスありがとうございます。
お陰様で解決しました!助かりました!!