PowerPoint (全般)

PowerPoint 全般に関する話題を扱うフォーラムです。
  • 掲示板への投稿には会員登録(無料)が必要です。会員登録がまだの方はこちら
  • 掲示板ご利用上のお願い」に反するご記入はご遠慮ください。
  • Q&A掲示板の使い方はこちらをご覧ください
トピックに返信
質問

 
(Windows 10全般 : PowerPoint 2013)
複数のPowerPointファイルのデザインテンプレートを切り替える方法
投稿日時: 17/11/04 15:50:10
投稿者: s-kikuchi

IT関連で研修講師をやっている者です。
ある時、ある企業から研修の依頼を受け、作成した自作の資料を使って研修を行おうとしたところ、
研修で使用するPowerPointの資料全てに企業ロゴを入れてほしい、という依頼をもらいました。
 
手作業で修正するのはちょっとした手間になってしまうため、お断りすることもできるのですが、
できることなら要望に応えたいと思っており、VBAを使って簡単にできる方法を模索しています。
 
XMLのデータの中にテンプレート名を指定している部分があるので、VBAを上手く利用することで
所定のフォルダの中にある、拡張子がpptxのファイルのテンプレートを一斉に置き換える、
または新規適用する、ということができないかなと試行錯誤しております。
 
※必ずしもVBAである必要はありません。
 
なにかうまい方法がございましたら、アドバイスいただければ幸いです。
 
以上、よろしくお願いいたします。

回答
投稿日時: 17/11/07 09:12:20
投稿者: んなっと

追加情報を待っていましたが、出そうにないので大雑把な回答をします。
 
●「テーマ」
C:\Program Files\Microsoft Office\Document Themes 14\Origin.thmx
を適用するなら
 
Sub test()
  Dim dlgOpen As FileDialog
  Dim Itm
  Dim Pre As Presentation
  Set dlgOpen = Application.FileDialog(msoFileDialogFilePicker)
  With dlgOpen
    .Filters.Add "PowerPoint", _
        "*.ppt; *.pps; *.pptx; *.pptm; *.ppsx; *.ppsm", 1
    '.InitialFileName = "E:\Office"
    If .Show <> -1 Then Exit Sub
  End With
  For Each Itm In dlgOpen.SelectedItems
    Set Pre = Presentations.Open(Itm)
    Pre.ApplyTemplate "C:\Program Files\Microsoft Office\Document Themes 14\Origin.thmx"
    'Pre.Save
    'Pre.Close
  Next
End Sub
 
●しかし、「テーマ」には「配色」「フォント」「効果」が含まれているので、
テーマを変更しただけで余計な部分も変わってしまう可能性が高いのです。
デザインテンプレートを適用するといっても単純ではないので、そのあたりの
追加情報を書き込んで欲しかったところです。
 
●別の方法です。
今回はスライドマスタに図を挿入するのがいいような気がします。
あらかじめ準備した画像 "E:\office\powerpoint\くま.png" を右下に挿入する例。
 
Sub test2()
  Dim dlgOpen As FileDialog
  Dim Itm
  Dim Pre As Presentation
  Set dlgOpen = Application.FileDialog(msoFileDialogFilePicker)
  With dlgOpen
    .Filters.Add "PowerPoint", _
        "*.ppt; *.pps; *.pptx; *.pptm; *.ppsx; *.ppsm", 1
    '.InitialFileName = "E:\Office"
    If .Show <> -1 Then Exit Sub
  End With
  For Each Itm In dlgOpen.SelectedItems
    Set Pre = Presentations.Open(Itm)
    Pre.SlideMaster.Shapes.AddPicture _
      FileName:="E:\office\powerpoint\くま.png", _
      LinkToFile:=msoFalse, SaveWithDocument:=msoTrue, _
      Left:=Pre.PageSetup.SlideWidth - 40, Top:=Pre.PageSetup.SlideHeight - 30, _
      Width:=40, Height:=30
    'Pre.Save
    'Pre.Close
  Next
End Sub

投稿日時: 17/11/11 09:45:13
投稿者: s-kikuchi

んなっと様
 
ご回答ありがとうございました。
また、回答の確認と追加情報を出すことができず、申し訳ありません。
 
いただいたコードで上手くテーマを切り替えることができるようになりました。
配色・フォント・効果といった適切なヒントもいただけましたので、この部分は自分で調べてなんとかすることができました。
質問前は、どんなキーワードを手がかりに調べたら良いかすら迷っている状態でしたので・・・
 
ありがとうございました。

トピックに返信